Arduino: Ethernet Web Server menampilkan isi Analog Input
Jump to navigation
Jump to search
Sumber: https://www.arduino.cc/en/Tutorial/WebServer
Dalam contoh ini, kita akan menggunakan Ethernet Shield dan Arduino atau Genuino board untuk membuat simple Web server. Menggunakan Ethernet library, device kita akan dapat menjawab HTTP request melalui Ethernet shield. Sesudah membuka browser dan navigating ke Ethernet shield IP address, Arduino akan meresponds dengan HTML secukupnya untuk browser agar dapat menampilkan nilai input dari ke enam analog pin yang ada.
Kebutuhan Hardware
- Arduino atau Genuino Board
- Arduino Ethernet Shield
Warning
Contoh ini tidak membutuhkan SD card. Jika SD card dimasukan dan tidak digunakan, kemungkinan sketch akan hang, karena pin 4 digunakan sebagai SS (active low) dari SD dan jika tidak digunakan dia akan di konfigurasi sebagai INPUT secara default.
Ada dua solusi
- Cabut SD card;
- Tambahkan line berikut di code di setup()
pinMode(4, OUTPUT); digitalWrite(4, HIGH);
Code
/*
Web Server
A simple web server that shows the value of the analog input pins.
using an Arduino Wiznet Ethernet shield.
Circuit:
* Ethernet shield attached to pins 10, 11, 12, 13
* Analog inputs attached to pins A0 through A5 (optional)
created 18 Dec 2009
by David A. Mellis
modified 9 Apr 2012
by Tom Igoe
modified 02 Sept 2015
by Arturo Guadalupi
*/
#include <SPI.h>
#include <Ethernet.h>
// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {
0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
IPAddress ip(192, 168, 0, 3);
// Initialize the Ethernet server library
// with the IP address and port you want to use
// (port 80 is default for HTTP):
EthernetServer server(80);
void setup() {
// Open serial communications and wait for port to open:
Serial.begin(9600);
while (!Serial) {
; // wait for serial port to connect. Needed for native USB port only
}
// start the Ethernet connection and the server:
Ethernet.begin(mac, ip);
server.begin();
Serial.print("server is at ");
Serial.println(Ethernet.localIP());
}
void loop() {
// listen for incoming clients
EthernetClient client = server.available();
if (client) {
Serial.println("new client");
// an http request ends with a blank line
boolean currentLineIsBlank = true;
while (client.connected()) {
if (client.available()) {
char c = client.read();
Serial.write(c);
// if you've gotten to the end of the line (received a newline
// character) and the line is blank, the http request has ended,
// so you can send a reply
if (c == '\n' && currentLineIsBlank) {
// send a standard http response header
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // the connection will be closed after completion of the response
client.println("Refresh: 5"); // refresh the page automatically every 5 sec
client.println();
client.println("<!DOCTYPE HTML>");
client.println("<html>");
// output the value of each analog input pin
for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
int sensorReading = analogRead(analogChannel);
client.print("analog input ");
client.print(analogChannel);
client.print(" is ");
client.print(sensorReading);
client.println("
");
}
client.println("</html>");
break;
}
if (c == '\n') {
// you're starting a new line
currentLineIsBlank = true;
} else if (c != '\r') {
// you've gotten a character on the current line
currentLineIsBlank = false;
}
}
}
// give the web browser time to receive the data
delay(1);
// close the connection:
client.stop();
Serial.println("client disconnected");
Ethernet.maintain();
}
}
Akses Web
Akses ke
http://192.168.0.3
akan tampil kira2
analog input 0 is 1023 analog input 1 is 1023 analog input 2 is 683 analog input 3 is 495 analog input 4 is 315 analog input 5 is 305