Arduino: Ethernet DHCP Address Printer

Sumber: https://www.arduino.cc/en/Tutorial/DhcpAddressPrinter

Sketch ini menggunakan DHCP extensions dari Ethernet library untuk memperoleh IP address via DHCP dan print IP address yang di peroleh menggunakan Arduino Ethernet shield.

DHCP menggunakan IP address yang dialokasikan saat Ethernet.begin(mac) dipanggil. Menggunakan DHCP akan sangat memperbesar size sketch. Menggunakan fungsi localIP(), alokasi IP address akan dikirim keluar melalui serial monitor.

Hardware yang dibutuhkan

• Arduino atau Genuino Board
• Arduino Ethernet Shield

Circuit

Ethernet shield mengijinkan anda untuk tersambung ke WizNet Ethernet controller ke board Arduino atau Genuino via SPI bus. Dia akan menggunakan pin 10, 11, 12, dan 13 untuk sambungan SPI ke WizNet. Model terakhir Ethernet shield memiliki SD Card on board. Digital pin 4 digunakan untuk control slave select di SD card.

Shield disambungkan ke jaringan dengan sebuah kabel ethernet. Kita perlu mengubah network setting di program sesuai dengan jaringan yang kita gunakan.

Code

/*
  DHCP-based IP printer 

  This sketch uses the DHCP extensions to the Ethernet library
  to get an IP address via DHCP and print the address obtained.
  using an Arduino Wiznet Ethernet shield. 

  Circuit:
   Ethernet shield attached to pins 10, 11, 12, 13

  created 12 April 2011
  modified 9 Apr 2012
  by Tom Igoe
  modified 02 Sept 2015
  by Arturo Guadalupi

*/

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address for your controller below.
// Newer Ethernet shields have a MAC address printed on a sticker on the shield
byte mac[] = {
  0x00, 0xAA, 0xBB, 0xCC, 0xDE, 0x02
};

// Initialize the Ethernet client library
// with the IP address and port of the server
// that you want to connect to (port 80 is default for HTTP):
EthernetClient client;

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  // this check is only needed on the Leonardo:
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port  only
  } 

  // start the Ethernet connection:
  if (Ethernet.begin(mac) == 0) {
    Serial.println("Failed to configure Ethernet using DHCP");
    // no point in carrying on, so do nothing forevermore:
    for (;;)
      ;
   }
  // print your local IP address:
  printIPAddress();
}

void loop() {

  switch (Ethernet.maintain())
  {
    case 1:
      //renewed fail
      Serial.println("Error: renewed fail");
      break;

    case 2:
      //renewed success
      Serial.println("Renewed success");

      //print your local IP address:
      printIPAddress();
      break;

    case 3:
      //rebind fail
      Serial.println("Error: rebind fail");
      break;

    case 4:
      //rebind success
      Serial.println("Rebind success"); 

      //print your local IP address:
      printIPAddress();
      break;

    default:
      //nothing happened
      break; 

  }
}

void printIPAddress()
{
  Serial.print("My IP address: ");
  for (byte thisByte = 0; thisByte < 4; thisByte++) {
    // print the value of each byte of the IP address:
    Serial.print(Ethernet.localIP()[thisByte], DEC);
    Serial.print(".");
  }

  Serial.println();
}

Referensi

• https://www.arduino.cc/en/Tutorial/DhcpAddressPrinter